TITLE   'Uniform Velocity of Injection at Re>>1'	         { sim241.pde }
SELECT     stages=7     ngrid=1     nodelimit=400     spectral_colors
VARIABLES     vx     vy     p  			{ Pressure minus ambient }
DEFINITIONS
   Lx=6     Ly=1.0      visc=1.0		{ Input velocities: }
   vx0=staged( 1e-6, 1e-4, 1e-3, 3e-3, 1e-2, 2e-2, 2e-2)	
   dens=1e3     Re=dens*vx0*2*Ly/visc	
   v=vector( vx, vy)     vm=magnitude( v)
   unit_x=vector(1,0)     unit_y=vector(0,1)
   nx=normal( unit_x)     ny=normal( unit_y)
   vxdvx=vx*dx( vx)+ vy*dy( vx)     vxdvy=vx*dx( vy)+ vy*dy( vy)
   natp=  if stage=7 then
               visc*[ nx*div( grad( vx))+ ny*div( grad( vy))]
              -dens*[ nx*vxdvx+  ny*vxdvy] else 0
   dens_term=  if stage=7 then dens*( dx( vxdvx)+ dy( vxdvy)) else 0
EQUATIONS
   vx:		dens*vxdvx+ dx( p)- visc*div( grad( vx))=0
   vy:		dens*vxdvy+ dy( p)- visc*div( grad( vy))=0
   p:		div( grad( p))+ dens_term- 1e4*visc/Ly^2*div( v)=0
BOUNDARIES
region 'domain'  start 'outer' (0,Ly)
   value( vx)=vx0   natural( vy)=0  natural( p)=natp    	 	{ In }
   line to (0,-Ly)    value( vx)=0   value( vy)=0   natural( p)=natp	{ Wall }
   line to (Lx,-Ly)	natural( vx)=0   value( vy)=0   value( p)=0	{ Out }
   line  to (Lx,Ly)  value( vx)=0   value( vy)=0   natural( p)=natp	{ Wall }
   line to close 									
PLOTS
   contour( vx/vx0) report( Re)
   vector( v) norm report(Re)     contour( vm) painted
   contour( p) painted     contour( div( v))     contour( curl( v)) painted
   elevation( vx) from (0,-Ly) to (0,Ly)
   elevation( vx) from (Lx/2,-Ly) to (Lx/2,Ly)
   elevation( vx) from (Lx,-Ly) to (Lx,Ly)
END