TITLE   'Particle Transmission in 1D'			         { sim181.pde }
SELECT     errlim=1e-4 				
COORDINATES    cartesian1			{ (x) only }
VARIABLES     psir     psii
DEFINITIONS						{ SI units throughout }
   Lx=3e-9     d=0.4e-9  	
   me=9.1096e-31 					{ Electron mass }
   h=6.6262e-34 						{ Planck?s constant }
   W=5e-19							{ Kinetic energy, fixed }	
   p=sqrt( 2*me*W)					{ Momentum }
   k=2*pi*p/h 						{ Wave number }
   c=8*pi^2*me/h^2					{ Coefficient for PDE }	
   psip=sqrt( psir^2+ psii^2)				{ Local peak value }
   V0=2.0*W     V 					{ Potential energy }	
EQUATIONS
   psir:	dxx(psir)- c*V*psir+ c*W*psir=0
   psii:	dxx(psii)- c*V*psii+ c*W*psii=0
BOUNDARIES
region 'forcefree'   V=0
   start (0)   point value( psir)=1   point value( psii)=0
   line to (Lx)   point natural( psir)=-k*psii   point natural( psii)=k*psir	
region 'barrier'   V=V0
   start (0) line to (d)
PLOTS
   elevation( psir, psii, psip) from (0) to (Lx) report( W/V0)
   elevation( psir, psii, psip) from (d) to (Lx) report( W/V0)
   elevation( psir^2, psii^2) from (0) to (Lx)
   elevation( psir^2, psii^2, psir^2+psii^2) from (d) to (Lx)
END